-- объявление переменных
DECLARE @name VARCHAR(50)  
DECLARE @path VARCHAR(256)  
DECLARE @fileName VARCHAR(256)  
DECLARE @fileDate VARCHAR(20)
 
-- размещение каталога, в который будут сохранены резервные копии
SET @path = 'C:\Backup\'
 
-- определение формата имени файлов резервной копии
SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),112) + '_' + 
REPLACE(CONVERT(VARCHAR(20),GETDATE(),108),':','')

DECLARE db_cursor CURSOR READ_ONLY FOR  
SELECT name 
FROM master.sys.databases
WHERE name NOT IN ('master','model','msdb','tempdb') -- исключаемые базы данных
AND state = 0         -- только БД в состоянии Online
AND is_in_standby = 0 -- только БД не находящиеся в режиме Read Only для Log shipping
 
OPEN db_cursor   
FETCH NEXT FROM db_cursor INTO @name   
 
WHILE @@FETCH_STATUS = 0   
BEGIN   
   SET @fileName = @path + @name + '_' + @fileDate + '.BAK'  
   BACKUP DATABASE @name TO DISK = @fileName  
 
   FETCH NEXT FROM db_cursor INTO @name   
END   

 
CLOSE db_cursor   
DEALLOCATE db_cursor