Вики IT-KB

В этой заметке представлен пример скрипта AppleScript для создания ISO образа из каталога в ОС Apple macOS.

-- Orig https://www.macscripter.net/t/create-iso-from-folder-or-cdr-files/73605
tell application "Finder"
 set SelectedItems to {}
 -- Образ будет создан для каждого выбранного каталога
 repeat with FilteredItem in (get selection)
  if class of FilteredItem is folder then set end of SelectedItems to FilteredItem
 end repeat
 set RootFolder to (container of FilteredItem) as text
end tell
--Проходим по каждому каталогу и запускаем обработчик для создания образа
repeat with SelectedItem in SelectedItems
 set toCovert to POSIX path of (RootFolder & name of SelectedItem)
 set thisISO to toCovert & ".iso"
 my createISO(toCovert, thisISO)
end repeat
 
on createISO(toCovert, thisISO)
 my DeleteIfExist(thisISO)
 try
  do shell script "hdiutil makehybrid -iso -joliet -o" & space & quoted form of thisISO & space & quoted form of toCovert
  display notification thisISO with title " " subtitle "Образ успешно создан"
 on error msg
  display dialog msg with title "Ошибка" with icon stop buttons {"OK"}
 end try
end createISO
 
on DeleteIfExist(thisISO)
 try
  POSIX file thisISO
  do shell script "rm -f" & space & quoted form of thisISO
 end try
end DeleteIfExist

Если из выбранного каталога ранее уже был создан образ, он будет автоматически удалён без уведомления пользователя.   Для удобства использования можно создать быстрое действие в Команды.app и выполнять запуск из пункта «Быстрые действия» контекстного меню.

Перед использованием, в настройках Команды.app необходимо разрешить использование скриптов. При первом запуске система несколько раз спросит о разрешениях запуска.

Проверено на следующих конфигурациях:

Автор первичной редакции:
Виталий Якоб
Время публикации: 08.07.2023 10:43